#!/usr/bin/perl -w
# If your perl isn't in /usr/bin then change the path above
# to reflect this sad fact.

# This little perl script was hacked together by Jens G Jensen
# and is distributed, as usual, without warranties of any kind
# etc blah blah, and under the Perl Artistic License in case
# you're interested.  <jens@argaeus.ma.rhbnc.ac.uk>

use strict;

# get the basename, assuming 'reasonable' characters are used
my $name = $0 =~ /[-_a-zA-Z0-9.]+$/ ? $& : $0;

# read options, if any
my $sc = 1; my $pl = 'ur';
my ($dx, $dy) = (0, 0);
while( @ARGV && $ARGV[0] =~ /^-((u|l)(l|r)|sc)$/ ) {
	my $opt = shift @ARGV;
	if( $1 eq 'sc' ) {
		$sc = shift @ARGV;
		unless( $sc =~ /^\d*\.?\d*$/ ) {
			print STDERR "$name: Warning: bad value $sc for -sc\n";
			unshift @ARGV, $sc;
			$sc = 1;
		}
	}
	else {
		$pl = $1;
		if( @ARGV && $ARGV[0] =~ /^(\d+),?(\d+)?$/ ) {
			shift @ARGV;
			$dx = $1;
			$dy = $2 ? $2 : $1;
		}
	}
}

unless( @ARGV ) {
	print STDERR <<USAGE;
$name: usage: $name [options] <logofile> [ <inputfile> ]
where
	options ::= placement [scale] | scale [placement]
	placement ::= -ul | -ur | -ll | -lr [<number>[,<number>]]
	scale ::= -sc <number>
and logofile should be an EPS file with your logo (this file must be
seekable), and inputfile should be some Postscript file (if omitted,
standard input is used).  $name will insert the eps file at the head of
each page (this is wasteful, but what do you expect from a quick hack
anyway?) so that it will print appropriately.  Placement allows you to
place relative to upper left (etc) corner, with an optional offset from
the corner (in postscript points, 1/72 of an inch).  If you specify
two numbers, separated by a comma and with no spaces between them,
then the first is offset in x-direction and the second in y-direction.
BUGS: ignores orientation, doesn't handle (atend) boundingbox in ps file.
USAGE
	exit(0);
}

my $fname = @ARGV > 1 ? $ARGV[1] : "-";
open(IN, "<$fname") or die "$name: Cannot open $fname for reading";

my (@bigbox, @smallbox);

# grep logofile for the boundingbox
open(EPS, "<$ARGV[0]")
	or die "$name: Cannot open include file $ARGV[0] for reading";
while(<EPS>) {
	if(/^%%BoundingBox:\s*(\d+)\s+(\d+)\s+(\d+)\s+(\d+)\s*$/) {
		@smallbox = ($1, $2, $3, $4);
		last;
	}
}
unless( defined @smallbox ) {
	print STDERR "$name: Fatal: I didn't find a valid boundingbox in $ARGV[0]\n";
	exit(1);
}

# Offset for placing the EPS within BBox
my ($x, $y) = (undef, undef);
while(<IN>) {
	print;
	if(/^%%BoundingBox:\s*(\d+)\s+(\d+)\s+(\d+)\s+(\d+)\s*$/) {
		@bigbox = ($1, $2, $3, $4);
	}
	if( /^%%Page:/ ) {
		unless( defined $x ) {
			unless( defined @bigbox ) {
				print STDERR <<WARN;
$name: Warning: didn't get a boundingbox before the first page (I can't
currently handle (atend) boundingboxes, since I assume input is streamed)
WARN
				($x, $y) = (0, 0);	# defaults, lower left (not what you wanted)
			}
			else {
				# usual hairy scary stuff
				if( $pl =~ /^u/ ) {
					$y = $bigbox[3]-$dy-$sc*($smallbox[3]-$smallbox[1]);
				}
				else {
					$y = $bigbox[1]+$dy;
				}
				if( $pl =~ /l$/ ) {
					$x = $bigbox[0]+$dx;
				}
				else {
					$x = $bigbox[2]-$dx-$sc*($smallbox[2]-$smallbox[0]);
				}
			}
		}
		print <<HEADER;
/foobiebletch save def
$x $y translate
$sc $sc scale
-$smallbox[0] -$smallbox[1] translate
%%BeginDocument
HEADER
		# include the entire EPS file (yeah, I know)
		# including boundingbox in this doc confuses gv
		seek EPS, 0, 0;
		while(<EPS>) { print unless /^%%(Page)?BoundingBox:/; }
		print <<FOOTER;
%%EndDocument
foobiebletch restore
FOOTER
	}
}

close EPS;
close IN;